SUMMARY = "Startup script and systemd unit file for the Weston Wayland compositor"
LICENSE = "MIT"
LIC_FILES_CHKSUM = "file://${COREBASE}/meta/COPYING.MIT;md5=3da9cfbcb788c80a0384361b4de20420"

SRC_URI = "file://westoninit \
           file://unisoc-weston-start \
           file://GLP3.0-weston-start \
          "

S = "${WORKDIR}"

do_install() {
	install -d ${D}${sysconfdir}/init.d
	install -m 0755 ${WORKDIR}/westoninit ${D}${sysconfdir}/init.d/westoninit

	# Install weston-start script
	install -d ${D}${bindir}/
	if [ "${DISTRO_CODENAME}" = "kirkstone" ]; then
		install -m 0755 ${WORKDIR}/GLP3.0-weston-start ${D}${bindir}/unisoc-weston-start
	else
		install -m 0755 ${WORKDIR}/unisoc-weston-start ${D}${bindir}/unisoc-weston-start
	fi
	sed -i 's,@DATADIR@,${datadir},g' ${D}${bindir}/unisoc-weston-start
	sed -i 's,@LOCALSTATEDIR@,${localstatedir},g' ${D}${bindir}/unisoc-weston-start
}

inherit allarch update-rc.d features_check

# rdepends on weston which depends on virtual/egl
REQUIRED_DISTRO_FEATURES = "opengl"

RDEPENDS:${PN} = "weston kbd"

INITSCRIPT_NAME = "westoninit"
INITSCRIPT_PARAMS = "${@bb.utils.contains('WESTON_BOARD', 'uis7885-2h10', 'start 20 S .', 'start 92 S .', d)}"