HOMEPAGE = "http://www.ofono.org"
SUMMARY  = "open source telephony"
DESCRIPTION = "oFono is a stack for mobile telephony devices on Linux. oFono supports speaking to telephony devices through specific drivers, or with generic AT commands."
LICENSE  = "GPLv2"
LIC_FILES_CHKSUM = "file://COPYING;md5=eb723b61539feef013de476e68b5c50a \
                    file://src/ofono.h;beginline=1;endline=21;md5=fcef373763fea2259d91d8cb6f4ff90c"

inherit autotools pkgconfig update-rc.d systemd  gobject-introspection-data

DEPENDS  = "dbus glib-2.0 udev mobile-broadband-provider-info libxml2 xmlparser "
DEPENDS += "${@bb.utils.contains('SUPPORT_VOICECALL','true','voicecall','',d)}"

export SUPPORT_LIBVOICECALL_FLAG="${@bb.utils.contains('SUPPORT_VOICECALL','true','-lvoicecall','',d)}"
export VOICECALL_FLAG = "${@bb.utils.contains('SUPPORT_VOICECALL','true','-DVOICECALL_SUPPORT','',d)}"

INITSCRIPT_NAME = "ofono"
INITSCRIPT_PARAMS = "start 51 S ."

PACKAGECONFIG ??= "\
    ${@bb.utils.filter('DISTRO_FEATURES', 'systemd', d)} \
    ${@bb.utils.contains('DISTRO_FEATURES', 'bluetooth', 'bluez', '', d)} \
    "
PACKAGECONFIG[systemd] = "--with-systemdunitdir=${systemd_unitdir}/system/,--with-systemdunitdir="
PACKAGECONFIG[bluez] = "--enable-bluetooth, --disable-bluetooth, bluez5"

SYSTEMD_SERVICE:${PN} = "ofono.service"

do_install:append() {
  install -d ${D}${sysconfdir}/init.d/
  install -m 0755 ${WORKDIR}/ofono ${D}${sysconfdir}/init.d/ofono
  install -d ${D}${systemd_unitdir}/system/
  install -m 0755 ${WORKDIR}/ofono.service ${D}${systemd_unitdir}/system
}


RDEPENDS:${PN} += "dbus libxml2 xmlparser "
RDEPENDS:${PN} += "${@bb.utils.contains('SUPPORT_VOICECALL','true','voicecall','',d)}"
RRECOMMENDS:${PN} += "kernel-module-tun mobile-broadband-provider-info"

FILES:${PN} += "${systemd_unitdir}"