214 lines
3.6 KiB
Plaintext
214 lines
3.6 KiB
Plaintext
/* SPDX-License-Identifier: GPL-2.0+ */
|
|
/*
|
|
* (C) Copyright 2013
|
|
* David Feng <[email protected]>
|
|
*
|
|
* (C) Copyright 2002
|
|
* Gary Jennejohn, DENX Software Engineering, <[email protected]>
|
|
*/
|
|
|
|
#include <config.h>
|
|
#include <asm/psci.h>
|
|
#include <version.h>
|
|
|
|
OUTPUT_FORMAT("elf64-littleaarch64", "elf64-littleaarch64", "elf64-littleaarch64")
|
|
OUTPUT_ARCH(aarch64)
|
|
ENTRY(_start)
|
|
SECTIONS
|
|
{
|
|
#ifdef CONFIG_ARMV8_SECURE_BASE
|
|
/DISCARD/ : { *(.rela._secure*) }
|
|
#endif
|
|
. = 0x00000000;
|
|
|
|
. = ALIGN(8);
|
|
.text :
|
|
{
|
|
__TEXT_START__ = .;
|
|
*(.__image_copy_start)
|
|
CPUDIR/start.o (.text*)
|
|
}
|
|
|
|
/* This needs to come before *(.text*) */
|
|
.efi_runtime : {
|
|
__efi_runtime_start = .;
|
|
. = ALIGN(4096);
|
|
__EFI_TEXT_START__ = .;
|
|
*(.text.efi_runtime*)
|
|
. = ALIGN(4096);
|
|
__EFI_RO_START__ = .;
|
|
*(.rodata.efi_runtime*)
|
|
. = ALIGN(4096);
|
|
__EFI_DATA_START__ = .;
|
|
*(.data.efi_runtime*)
|
|
. = ALIGN(4096);
|
|
__EFI_END__ = .;
|
|
__efi_runtime_stop = .;
|
|
}
|
|
. = ALIGN(4096);
|
|
__TEXT_REAL_START__ = .;
|
|
.text_rest :
|
|
{
|
|
*(.text*)
|
|
}
|
|
|
|
. = ALIGN(4096);
|
|
__TEXT_END__ = .;
|
|
#ifdef CONFIG_ARMV8_PSCI
|
|
.__secure_start :
|
|
#ifndef CONFIG_ARMV8_SECURE_BASE
|
|
ALIGN(CONSTANT(COMMONPAGESIZE))
|
|
#endif
|
|
{
|
|
KEEP(*(.__secure_start))
|
|
}
|
|
|
|
#ifndef CONFIG_ARMV8_SECURE_BASE
|
|
#define CONFIG_ARMV8_SECURE_BASE
|
|
#define __ARMV8_PSCI_STACK_IN_RAM
|
|
#endif
|
|
.secure_text CONFIG_ARMV8_SECURE_BASE :
|
|
AT(ADDR(.__secure_start) + SIZEOF(.__secure_start))
|
|
{
|
|
*(._secure.text)
|
|
}
|
|
|
|
.secure_data : AT(LOADADDR(.secure_text) + SIZEOF(.secure_text))
|
|
{
|
|
*(._secure.data)
|
|
}
|
|
|
|
.secure_stack ALIGN(ADDR(.secure_data) + SIZEOF(.secure_data),
|
|
CONSTANT(COMMONPAGESIZE)) (NOLOAD) :
|
|
#ifdef __ARMV8_PSCI_STACK_IN_RAM
|
|
AT(ADDR(.secure_stack))
|
|
#else
|
|
AT(LOADADDR(.secure_data) + SIZEOF(.secure_data))
|
|
#endif
|
|
{
|
|
KEEP(*(.__secure_stack_start))
|
|
|
|
. = . + CONFIG_ARMV8_PSCI_NR_CPUS * ARM_PSCI_STACK_SIZE;
|
|
|
|
. = ALIGN(CONSTANT(COMMONPAGESIZE));
|
|
|
|
KEEP(*(.__secure_stack_end))
|
|
}
|
|
|
|
#ifndef __ARMV8_PSCI_STACK_IN_RAM
|
|
. = LOADADDR(.secure_stack);
|
|
#endif
|
|
|
|
.__secure_end : AT(ADDR(.__secure_end)) {
|
|
KEEP(*(.__secure_end))
|
|
LONG(0x1d1071c); /* Must output something to reset LMA */
|
|
}
|
|
#endif
|
|
|
|
. = ALIGN(4096);
|
|
__RO_START__ = .;
|
|
.__rodata_start :
|
|
{
|
|
*(.__rodata_start)
|
|
}
|
|
.rodata : { *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*))) }
|
|
. = ALIGN(4096);
|
|
__RO_END__ = .;
|
|
#ifdef CONFIG_AML_UASAN
|
|
/* uasan global register */
|
|
.init_array :
|
|
{
|
|
__init_array_start = .;
|
|
KEEP(*(.init_array))
|
|
__init_array_end = .;
|
|
}
|
|
#endif
|
|
|
|
. = ALIGN(4096);
|
|
__DATA_START__ = .;
|
|
.data : {
|
|
*(.data*)
|
|
}
|
|
|
|
. = ALIGN(4096);
|
|
__DATA_END__ = .;
|
|
. = .;
|
|
|
|
. = ALIGN(8);
|
|
.u_boot_list : {
|
|
KEEP(*(SORT(.u_boot_list*)));
|
|
}
|
|
|
|
. = ALIGN(8);
|
|
|
|
.efi_runtime_rel : {
|
|
__efi_runtime_rel_start = .;
|
|
*(.rel*.efi_runtime)
|
|
*(.rel*.efi_runtime.*)
|
|
__efi_runtime_rel_stop = .;
|
|
}
|
|
|
|
. = ALIGN(8);
|
|
|
|
.image_copy_end :
|
|
{
|
|
*(.__image_copy_end)
|
|
}
|
|
|
|
. = ALIGN(8);
|
|
|
|
.rel_dyn_start :
|
|
{
|
|
*(.__rel_dyn_start)
|
|
}
|
|
|
|
.rela.dyn : {
|
|
*(.rela*)
|
|
}
|
|
|
|
.rel_dyn_end :
|
|
{
|
|
*(.__rel_dyn_end)
|
|
}
|
|
|
|
#ifdef CONFIG_FULL_RAMDUMP
|
|
. = ALIGN(4096);
|
|
#endif
|
|
|
|
#ifdef CONFIG_NASC_NAGRA_TIER_1
|
|
. = ALIGN(4096);
|
|
#endif
|
|
|
|
_end = .;
|
|
|
|
. = ALIGN(4096);
|
|
__BSS_START__ = .;
|
|
|
|
.bss_start : {
|
|
KEEP(*(.__bss_start));
|
|
}
|
|
|
|
.bss : {
|
|
*(.bss*)
|
|
. = ALIGN(8);
|
|
}
|
|
|
|
.bss_end : {
|
|
KEEP(*(.__bss_end));
|
|
}
|
|
|
|
. = ALIGN(4096);
|
|
__BSS_END__ = .;
|
|
|
|
/DISCARD/ : { *(.dynsym) }
|
|
/DISCARD/ : { *(.dynstr*) }
|
|
/DISCARD/ : { *(.dynamic*) }
|
|
/DISCARD/ : { *(.plt*) }
|
|
/DISCARD/ : { *(.interp*) }
|
|
/DISCARD/ : { *(.gnu*) }
|
|
|
|
#ifdef CONFIG_LINUX_KERNEL_IMAGE_HEADER
|
|
#include "linux-kernel-image-header-vars.h"
|
|
#endif
|
|
}
|